summaryrefslogtreecommitdiff
path: root/modules/openstack_project/manifests/grafana.pp
blob: 2f245032097d843b5783fcfa9793efe40b6dc148 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
# == Class: openstack_project::grafana
#
# === Parameters
# [*cfg*]
# Manages the Grafana configuration file. The upstream puppet-grafana module
# documentaion: https://github.com/bfraser/puppet-grafana#cfg
#
class openstack_project::grafana (
  $mysql_password,
  $admin_password = '',
  $admin_user = 'admin',
  $grafana_cfg = {},
  $http_host = '127.0.0.1',
  $http_port = '8080',
  $mysql_host = '127.0.0.1',
  $mysql_name = 'grafana',
  $mysql_user = 'grafana',
  $project_config_repo = '',
  $secret_key = '',
  $vhost_name = $::fqdn,
) {
  include ::httpd

  $grafana_cfg_defaults = {
    # NOTE(pabelanger): app_mode must be the first key!
    'app_mode' => 'production',
    'analytics' => {
      'reporting_enabled' => false,
    },
    'auth.anonymous' => {
      'enabled' => true,
    },
    'database' => {
      'type'     => 'mysql',
      'host'     => "${mysql_host}:3306",
      'name'     => $mysql_name,
      'user'     => $mysql_user,
      'password' => $mysql_password,
    },
    'security' => {
      'admin_password' => $admin_password,
      'admin_user'     => $admin_user,
      'secret_key'     => $secret_key,
    },
    'server'   => {
      'http_addr' => $http_host,
      'http_port' => $http_port,
    },
    'users'    => {
      'allow_sign_up' => false,
    },
  }

  $grafana_cfg_merged = merge($grafana_cfg_defaults, $grafana_cfg)

  class { '::grafana':
    cfg            => $grafana_cfg_merged,
    # Note that we can't use archive because that install_method requires
    # the camptocamp-archive module but we have puppetcommunity-archive
    # in modules.env, and puppet only supports having one in the modulepath
    # at a time.
    install_method => 'repo',
    version        => '2.6.0',
  }

  ::httpd::vhost { $vhost_name:
    docroot  => 'MEANINGLESS ARGUMENT',
    port     => 80,
    priority => '50',
    template => 'openstack_project/grafana.vhost.erb',
  }

  if ! defined(Httpd::Mod['rewrite']) {
    httpd::mod { 'rewrite':
        ensure => present,
    }
  }

  if ! defined(Httpd::Mod['proxy']) {
    httpd::mod { 'proxy':
        ensure => present,
    }
  }

  if ! defined(Httpd::Mod['proxy_http']) {
    httpd::mod { 'proxy_http':
        ensure => present,
    }
  }

  class { '::project_config':
    url  => $project_config_repo,
  }

  class { '::grafyaml':
    config_dir  => $::project_config::grafana_dashboards_dir,
    grafana_url => "http://${admin_user}:${admin_password}@${http_host}:${http_port}",
    require     => Class['grafana'],
  }
}