openstack
/
puppet-neutron
Code Issues Proposed changes

Add LBaaS Support 

Since OpenStack Quantum has a LBaaS agent in Grizzly release,
this patch install and configure it with the default driver : HAproxy.

Change-Id: I68af63c33f6f5cd712a66dc747d3da8d01222aeb
This commit is contained in:
Émilien Macchi 2013-07-02 23:31:00 +02:00
parent b7fd8204d0
commit dc7d620a31
6 changed files with 251 additions and 0 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

1
examples/quantum.pp
View File

@ -18,6 +18,7 @@ class { 'quantum::server':
# Various agents
class { 'quantum::agents::dhcp': }
class { 'quantum::agents::l3': }
class { 'quantum::agents::lbaas': }
# This plugin configures Quantum for OVS on the server
# Agent

22
lib/puppet/provider/quantum_lbaas_agent_config/ini_setting.rb Normal file
View File

@ -0,0 +1,22 @@
Puppet::Type.type(:quantum_lbaas_agent_config).provide(
:ini_setting,
:parent => Puppet::Type.type(:ini_setting).provider(:ruby)
) do
def section
resource[:name].split('/', 2).first
end
def setting
resource[:name].split('/', 2).last
end
def separator
'='
end
def file_path
'/etc/quantum/lbaas_agent.ini'
end
end

18
lib/puppet/type/quantum_lbaas_agent_config.rb Normal file
View File

@ -0,0 +1,18 @@
Puppet::Type.newtype(:quantum_lbaas_agent_config) do
ensurable
newparam(:name, :namevar => true) do
desc 'Section/setting name to manage from lbaas_agent.ini'
newvalues(/\S+\/\S+/)
end
newproperty(:value) do
desc 'The value of the setting to be defined.'
munge do |value|
value = value.to_s.strip
value.capitalize! if value =~ /^(true|false)$/i
value
end
end
end

95
manifests/agents/lbaas.pp Normal file
View File

@ -0,0 +1,95 @@
# == Class: quantum::agents:lbaas:
#
# Setups Quantum Load Balancing agent.
#
# === Parameters
#
# [*package_ensure*]
# (optional) Ensure state for package. Defaults to 'present'.
#
# [*enabled*]
# (optional) Enable state for service. Defaults to 'true'.
#
# [*debug*]
# (optional) Show debugging output in log. Defaults to false.
#
# [*interface_driver*]
# (optional) Defaults to 'quantum.agent.linux.interface.OVSInterfaceDriver'.
#
# [*device_driver*]
# (optional) Defaults to 'quantum.plugins.services.agent_loadbalancer.drivers.haproxy.namespace_driver.HaproxyNSDriver'.
#
# [*use_namespaces*]
# (optional) Allow overlapping IP (Must have kernel build with
# CONFIG_NET_NS=y and iproute2 package that supports namespaces).
# Defaults to true.
#
# [*user_group*]
# (optional) The user group. Defaults to nogroup.
#
class quantum::agents::lbaas (
$package_ensure = present,
$enabled = true,
$debug = false,
$interface_driver = 'quantum.agent.linux.interface.OVSInterfaceDriver',
$device_driver = 'quantum.plugins.services.agent_loadbalancer.drivers.haproxy.namespace_driver.HaproxyNSDriver',
$use_namespaces = true,
$user_group = 'nogroup',
) {
include quantum::params
Quantum_config<||> ~> Service['quantum-lbaas-service']
Quantum_lbaas_agent_config<||> ~> Service['quantum-lbaas-service']
case $device_driver {
/\.haproxy/: {
Package['haproxy'] -> Package<| title == 'quantum-lbaas-agent' |>
package { 'haproxy':
name => $::quantum::params::haproxy_package,
ensure => present,
}
}
default: {
fail("Unsupported device_driver ${device_driver}")
}
}
# The LBaaS agent loads both quantum.ini and its own file.
# This only lists config specific to the agent. quantum.ini supplies
# the rest.
quantum_lbaas_agent_config {
'DEFAULT/debug': value => $debug;
'DEFAULT/interface_driver': value => $interface_driver;
'DEFAULT/device_driver': value => $device_driver;
'DEFAULT/use_namespaces': value => $use_namespaces;
'DEFAULT/user_group': value => $user_group;
}
if $::quantum::params::lbaas_agent_package {
Package['quantum'] -> Package['quantum-lbaas-agent']
Package['quantum-lbaas-agent'] -> Quantum_config<||>
Package['quantum-lbaas-agent'] -> Quantum_lbaas_agent_config<||>
package { 'quantum-lbaas-agent':
name => $::quantum::params::lbaas_agent_package,
ensure => $package_ensure,
}
} else {
# Some platforms (RedHat) do not provide a quantum LBaaS agent package.
# The quantum LBaaS agent config file is provided by the quantum package.
Package['quantum'] -> Quantum_lbaas_agent_config<||>
}
if $enabled {
$ensure = 'running'
} else {
$ensure = 'stopped'
}
service { 'quantum-lbaas-service':
name => $::quantum::params::lbaas_agent_service,
enable => $enabled,
ensure => $ensure,
require => Class['quantum'],
}
}

10
manifests/params.pp
View File

@ -20,6 +20,11 @@ class quantum::params {
$dnsmasq_packages = ['dnsmasq', 'dnsmasq-utils']
$lbaas_agent_package = false
$lbaas_agent_service = 'quantum-lbaas-agent'
$haproxy_package = 'haproxy'
$l3_agent_package = false
$l3_agent_service = 'quantum-l3-agent'
@ -48,6 +53,11 @@ class quantum::params {
$dhcp_agent_package = 'quantum-dhcp-agent'
$dhcp_agent_service = 'quantum-dhcp-agent'
$lbaas_agent_package = 'quantum-lbaas-agent'
$lbaas_agent_service = 'quantum-lbaas-agent'
$haproxy_package = 'haproxy'
$metadata_agent_package = 'quantum-metadata-agent'
$metadata_agent_service = 'quantum-metadata-agent'

105
spec/classes/quantum_agents_lbaas_spec.rb Normal file
View File

@ -0,0 +1,105 @@
require 'spec_helper'
describe 'quantum::agents::lbaas' do
let :pre_condition do
"class { 'quantum': rabbit_password => 'passw0rd' }"
end
let :params do
{}
end
let :default_params do
{ :package_ensure => 'present',
:enabled => true,
:debug => false,
:interface_driver => 'quantum.agent.linux.interface.OVSInterfaceDriver',
:device_driver => 'quantum.plugins.services.agent_loadbalancer.drivers.haproxy.namespace_driver.HaproxyNSDriver',
:use_namespaces => true,
:user_group => 'nogroup',
}
end
shared_examples_for 'quantum lbaas agent' do
let :p do
default_params.merge(params)
end
it { should include_class('quantum::params') }
it_configures 'haproxy lbaas_driver'
it 'configures lbaas_agent.ini' do
should contain_quantum_lbaas_agent_config('DEFAULT/debug').with_value(p[:debug]);
should contain_quantum_lbaas_agent_config('DEFAULT/interface_driver').with_value(p[:interface_driver]);
should contain_quantum_lbaas_agent_config('DEFAULT/device_driver').with_value(p[:device_driver]);
should contain_quantum_lbaas_agent_config('DEFAULT/use_namespaces').with_value(p[:use_namespaces]);
should contain_quantum_lbaas_agent_config('DEFAULT/user_group').with_value(p[:user_group]);
end
it 'installs quantum lbaas agent package' do
if platform_params.has_key?(:lbaas_agent_package)
should contain_package('quantum-lbaas-agent').with(
:name => platform_params[:lbaas_agent_package],
:ensure => p[:package_ensure]
)
should contain_package('quantum').with_before(/Package\[quantum-lbaas-agent\]/)
should contain_package('quantum-lbaas-agent').with_before(/Quantum_lbaas_agent_config\[.+\]/)
should contain_package('quantum-lbaas-agent').with_before(/Quantum_config\[.+\]/)
else
should contain_package('quantum').with_before(/Quantum_lbaas_agent_config\[.+\]/)
end
end
it 'configures quantum lbaas agent service' do
should contain_service('quantum-lbaas-service').with(
:name => platform_params[:lbaas_agent_service],
:enable => true,
:ensure => 'running',
:require => 'Class[Quantum]'
)
end
end
shared_examples_for 'haproxy lbaas_driver' do
it 'installs haproxy packages' do
if platform_params.has_key?(:lbaas_agent_package)
should contain_package('haproxy').with_before('Package[quantum-lbaas-agent]')
end
should contain_package('haproxy').with(
:ensure => 'present',
:name => platform_params[:haproxy_package]
)
end
end
context 'on Debian platforms' do
let :facts do
{ :osfamily => 'Debian' }
end
let :platform_params do
{ :haproxy_package => 'haproxy',
:lbaas_agent_package => 'quantum-lbaas-agent',
:lbaas_agent_service => 'quantum-lbaas-agent' }
end
it_configures 'quantum lbaas agent'
end
context 'on RedHat platforms' do
let :facts do
{ :osfamily => 'RedHat' }
end
let :platform_params do
{ :haproxy_package => 'haproxy',
:lbaas_agent_service => 'quantum-lbaas-agent' }
end
it_configures 'quantum lbaas agent'
end
end